Drax requires no beer for teaching hunting skills

[AmProsius]

Drax teaches hunting skills no matter if the player gives him a beer or not.

[catalinstoian]

gothic-1-community-patch/scriptbase/_work/Data/Scripts/Content/Story/Missions/DIA_ORG_819_Drax.d

Lines 80 to 109 in e66b303

	FUNC VOID Org_819_Drax_Scavenger_Info()
	{
	if (Npc_HasItems(other,itfobeer)>0)
	{
	B_GiveInvItems (other, self, itfobeer,1);
	AI_Output (other, self,"Org_819_Drax_Scavenger_15_00"); //Here you are, take a beer and tell me about hunting.
	if ( C_BodystateContains(self, BS_SIT) )
	{
	AI_StandUp (self);
	AI_TurnToNpc (self, hero);
	};
	AI_UseItem (self, ItFobeer);
	AI_Output (self, other,"Org_819_Drax_Scavenger_06_01"); //Scavengers, that's what we call the big birds, should be attacked one after the other. It's easy to lure single scavengers from the pack.
	AI_Output (self, other,"Org_819_Drax_Scavenger_06_02"); //If you come too close, they'll become irritated. After a while they'll storm in your direction. At this point, you should be waiting for them with a raised weapon.
	AI_Output (self, other,"Org_819_Drax_Scavenger_06_03"); //If you manage to strike the beast before it hits you, you have to keep fighting, then you'll be able to defeat the creature without being hurt yourself.
	AI_Output (self, other,"Org_819_Drax_Scavenger_06_04"); //If it hits YOU first - well - just don't let them.
	drax_bierbekommen = TRUE;
	}
	else
	{
	AI_Output (other, self,"Org_819_Drax_Scavenger_KEIN_BIER_15_00"); //I don't have any beer.
	AI_Output (self, other,"Org_819_Drax_Scavenger_KEIN_BIER_06_01"); //Then go and fetch some. That'll be the best free hint you'll get in a long time. And as you're going anyway, bring some ore with you as well!
	AI_Output (self, other,"Org_819_Drax_Scavenger_KEIN_BIER_06_02"); //I can give you some information about animals, but it'll cost you!
	};
	drax_Lehrer_frei = TRUE;
	Log_CreateTopic (GE_TeacherOW, LOG_NOTE);
	B_LogEntry (GE_TeacherOW,"The rogue Drax offered to teach me about the gutting of animals if I can pay his prices. He hunts on the way from the trading square to the Old Camp.");
	};

changed to

FUNC VOID  Org_819_Drax_Scavenger_Info()
{
	if (Npc_HasItems(other,itfobeer)>=1)
	{
		B_GiveInvItems	(other, self, itfobeer,1);
	
		AI_Output	(other, self,"Org_819_Drax_Scavenger_15_00"); //Here you are, take a beer and tell me about hunting.
		if ( C_BodystateContains(self, BS_SIT) )
		{
			AI_StandUp		(self);
			AI_TurnToNpc	(self, hero);
		};
		AI_UseItem	(self,	ItFobeer);
		AI_Output	(self, other,"Org_819_Drax_Scavenger_06_01"); //Scavengers, that's what we call the big birds, should be attacked one after the other. It's easy to lure single scavengers from the pack.
		AI_Output	(self, other,"Org_819_Drax_Scavenger_06_02"); //If you come too close, they'll become irritated. After a while they'll storm in your direction. At this point, you should be waiting for them with a raised weapon.
		AI_Output	(self, other,"Org_819_Drax_Scavenger_06_03"); //If you manage to strike the beast before it hits you, you have to keep fighting, then you'll be able to defeat the creature without being hurt yourself.
		AI_Output	(self, other,"Org_819_Drax_Scavenger_06_04"); //If it hits YOU first - well - just don't let them.
		drax_bierbekommen = TRUE;
		drax_Lehrer_frei = TRUE;
		Log_CreateTopic	(GE_TeacherOW, LOG_NOTE);
		B_LogEntry	(GE_TeacherOW,"The rogue Drax offered to teach me about the gutting of animals if I can pay his prices. He hunts on the way from the trading square to the Old Camp.");
	}
	else
	{
		AI_Output (other, self,"Org_819_Drax_Scavenger_KEIN_BIER_15_00"); //I don't have any beer.
		AI_Output (self, other,"Org_819_Drax_Scavenger_KEIN_BIER_06_01"); //Then go and fetch some. That'll be the best free hint you'll get in a long time. And as you're going anyway, bring some ore with you as well!
		AI_Output (self, other,"Org_819_Drax_Scavenger_KEIN_BIER_06_02"); //I can give you some information about animals, but it'll cost you!
	};	
};